Most Valuable Professional


View Jan Karel Pieterse's profile on LinkedIn subscribe to rss feed
Subscribe in a reader

Subscribe to our mailing list

* indicates required

Audit !!!

Check out our RefTreeAnalyser
the ultimate Excel formula auditing tool.

Trainings

Excel VBA Masterclass (English)
Excel VBA for Financials (Dutch)

Third party tools

Speed up your file

FastExcel
The best tool to optimise your Excel model!

Repair your file

Stellar Phoenix Excel Repair
Best tool to repair corrupt Excel sheets and objects
Home > English site > Articles > Pivottable Slicers > Show Selected Items

Showing selected Slicer items on a worksheet

Even though it is often sufficient to see the slicer on the workbook it can be useful to be able to get a list of the filtered sliceritems in a worksheet cell. If your pivottable is built using a powerpivot model, then you can access this information by using the CUBERANKEDMEMBER worksheet function. If however the slicer was built off of a "normal" pivottable, then you need a bit of VBA code in a User Defined Function (UDF).

The slicer name

In order to retrieve the selected slicer items we need slicer's internal name, both for the CUBERANKEDMEMBER function and for the UDF. This name can be shown in the userinterface by right-clicking the slicer in question and selecting "Slicer settings". The name you are looking for is marked in red in the screenshot below and indicated by "Name to use in formulas":

Slicer settings dialog, needed name highlighted in red

CUBERANKEDMEMBER (for powerpivot slicers)

The CUBERANKEDMEMBER function returns an array of selected items and hence needs to be into as many (vertical) cells as you expect will be selected in the slicer. See the screenshot below (note the formula has ; as the delimiter, many users need to use the comma instead).

Using the CUBERANKEDMEMBER function

Note, that when less items are selected than the number of cells the function was entered into, the excess cells will show #N/A.

These #N/A's can be hidden with:

=IFERROR(CUBERANKEDMEMBER("PowerPivot Data",Slicer_Name,ROW()-ROW($G$5)),"")

or counted with

=IF(ROW()-ROW($G$5)<=CUBESETCOUNT(CUBESET("PowerPivot Data",Slicer_Name)),CUBERANKEDMEMBER("PowerPivot Data",Slicer_Name,ROW()-ROW($G$5)),"")

The UDF

The code sample below must be placed in a normal module:

Public Function GetSelectedSlicerItems(SlicerName As String) As String
    Dim oSc As SlicerCache
    Dim oSi As SlicerItem
    Dim lCt As Long
    On Error Resume Next
    Application.Volatile
    Set oSc = ThisWorkbook.SlicerCaches(SlicerName)
    If Not oSc Is Nothing Then
        For Each oSi In oSc.SlicerItems
            If oSi.Selected Then
                GetSelectedSlicerItems = GetSelectedSlicerItems & oSi.Name & ", "
                lCt = lCt + 1
            End If
        Next
        If Len(GetSelectedSlicerItems) > 0 Then
            If lCt = oSc.SlicerItems.Count Then
                GetSelectedSlicerItems = "All Items"
            Else
                GetSelectedSlicerItems = Left(GetSelectedSlicerItems, Len(GetSelectedSlicerItems) - 2)
            End If
        Else
            GetSelectedSlicerItems = "No items selected"
        End If
    Else
        GetSelectedSlicerItems = "No slicer with name '" & SlicerName & "' was found"
    End If
End Function

The function takes the slicername as its argument and returns a text string (comma delimited) containing the selected items. In a worksheet cell the formula would look like this:

=GetSelectedSlicerItems("Slicer_TeamID2")

Conclusion

Well, I hope I got you started with getting your head around how slicers work and how to address them using VBA. I find Slicers a real gem in Excel 2010 and 2013. A great addition to the product!

 


 


Comments

Showing last 8 comments of 167 in total (Show All Comments):

 


Comment by: Jan Karel Pieterse (3-6-2019 09:40:00)

Hi Cat,

I'm not sure why you think the function is volatile, it shouldn't be (there is no Application.Volatile in there).

 


Comment by: LEO MANSI (18-9-2019 15:42:00)

This code is great when the slicer is linked to a PivotTable. But when the slicer is linked to a Table, the function returns "No slicer with name 'Slicer_ProposalType' was found", where Slicer_ProposalType is the name of my slicer. Is there a way to get it to work with a slicer that is linked to a table?

Thank you!

 


Comment by: Jan Karel Pieterse (18-9-2019 15:55:00)

Hi Leo,

This one works fine for me:
Public Function GetSelectedSlicerItems(SlicerName As String, Optional ReturnArray As Boolean = False, _
                                     Optional CountNoDataItems As Boolean = False) As Variant
    Dim oSc As SlicerCache
    Dim oSi As SlicerItem
    Dim oSItems As SlicerItems
    Dim lCt As Long
    On Error Resume Next
    Application.Volatile
    Set oSc = ActiveWorkbook.SlicerCaches(SlicerName)
    If Not oSc Is Nothing Then
        Err.Clear
        Set oSItems = oSc.SlicerCacheLevels(1).SlicerItems
        If Err.Number > 0 Then
            Set oSItems = oSc.SlicerItems
        End If
        For Each oSi In oSItems
            If oSi.Selected And (oSi.HasData Or CountNoDataItems) Then
                GetSelectedSlicerItems = GetSelectedSlicerItems & oSi.Name & ","
                lCt = lCt + 1
            ElseIf oSi.HasData = False And CountNoDataItems Then
                lCt = lCt + 1
            End If
        Next
        If Len(GetSelectedSlicerItems) > 0 Then
            If lCt = oSItems.Count Then
                GetSelectedSlicerItems = "All Items"
            Else
                If ReturnArray Then
                    GetSelectedSlicerItems = Application.Transpose(Split(GetSelectedSlicerItems, ","))
                End If
            End If
        Else
            GetSelectedSlicerItems = "No items selected"
        End If
    Else
        GetSelectedSlicerItems = "No slicer with name '" & SlicerName & "' was found"
    End If
End Function

 


Comment by: LEO MANSI (18-9-2019 16:24:00)

Thank you! Works great

 


Comment by: Chams (21-9-2019 13:52:00)

Hi JAn,

Last code for slicer of normal table is always give error feedback when used as function ?? what might be the issue.


I convert the function into normal sub to run in command bottom then it worked fine,

what might be the issue?

 


Comment by: Jan Karel Pieterse (23-9-2019 11:02:00)

Hi Chams,

Are you referring to this comment:
https://jkp-ads.com/Articles/slicers05.asp?AllComments=True#29198

What kind of error are you getting precisely?

 


Comment by: Jamie (7-10-2019 17:41:00)

HI Jan

Your last piece of code works great with the table I've assigned to my pivot. Although it brings back [table].[column].[Data] . Is it possible only to show Data in the returned cell ? ..

 


Comment by: Jan Karel Pieterse (8-10-2019 21:23:00)

Hi Jamie,

You coule use the Split function in VBA to split the returned text by the period and then only return the last item of the array Split gives you:

GetSelectedSlicerItems = GetSelectedSlicerItems & Split(oSi.Name, ".")(Ubound(Split(oSi.Name, ".")) & ","

 


Have a question, comment or suggestion? Then please use this form.

If your question is not directly related to this web page, but rather a more general "How do I do this" Excel question, then I advise you to ask your question here: www.eileenslounge.com.

Please enter your name (required):

Your e-mail address (optional, will only be used to inform you when your comment is published or to respond to your question directly):

Your request or comment (max 2000 characters):

To post VBA code in your comment, use [VB] tags, like this: [VB]Code goes here[/VB].

I give permission to process this data and display my name and my comment on this website accoring to our Privacy Policy.