Een wiskundige vergelijking grafisch weergeven met behulp van Excel en gedefinieerde namen

Pagina's in dit artikel

  1. Inleiding
  2. De Grafiek
  3. x waarden
  4. y waarden
  5. Voorbeelden

X waarden verkrijgen

De volgende opdracht is om een lijst met x waarden te creeren voor de grafiek. Een relatief onbekend gegeven is dat de formule in een gedefinieerde naam standaard door Excel wordt behandeld als een matrix formule. Dit feit zullen we dankbaar gebruiken.

Allereerst hebben we een serie oplopende getallen nodig. Hiervoor gebruiken we de RIJ functie.

We definiëren deze lokale naam op Sheet1:

Naam: Sheet1!x

Verwijst Naar: =RIJ(1:20)

Als we nu de cellen A1:A20 selecteren en de volgende formule intypen: =x en bevestigen met control-shift-enter, dan krijgen we het volgende resultaat:

Resultaat van de formule =x in cellen A1 tot en met A20

We wilden echter het aantal x waarden laten afhangen van een waarde in een cel. Hiervoor gebruiken we de VERSCHUIVING functie:

=RIJ(VERSCHUIVING(Sheet1!$A$1;0;0;20;1))

Als we de bovenstaande formule in de naam Sheet!x plaatsen, dan blijft het resultaat van bovenstaand plaatje onveranderd.
Nu hoeven we alleen nog de "20" te vervangen door een celverwijzing:

=RIJ(VERSCHUIVING(Sheet1!$A$1;0;0;Sheet1!$B$5;1))

Nu hebben we de getallen 1 tot en met 20 (of wat ook het aantal is dat we in cel B5 hebben ingevoerd)

Maar we wilden ook een maximum en minimum waarde kunnen opgeven voor onze grafiek en daarbij de getallen 1 t/m 20 gebruiken om dit bereik te vullen met waarden.

We definiëren deze namen:

Naam
verwijst naar:
xStart
=Sheet1!$B$3
xEnd
=Sheet1!$B$4
xNumberOfPoints
=Sheet1!$B$5
xRange
=xEnd-xStart

Om een serie "xNumberOfPoints" van xStart tot xEnd te verkrijgen, kunnen we de volgende vergelijking toepasen

xPoint=xStart+xRange/(xNumberOfPoints-1)*Counter(1 to xNumberOfPoints-1)

Als we de bovenstaande benadering toepassen met behulp van bovenstaande gedefinieerde namen:

=xStart+xRange/(xNumberOfPoints-1)*(RIJ(VERSCHUIVING(Sheet1!$A$1;0;0;xNumberOfPoints;1))-1)

We zullen deze nieuwe formule (verrassing!) Sheet1!x noemen.

Opmerking:

Het bewerken en maken van gedefinieerde namen is veel eenvoudiger met de gratis Name Manager.